【教程】Prolog和人工智能

为什么要Prolog
　　看完上面的例子，不知道是否提起了你对prolog的兴趣。如果你感兴趣的话，那么让我们继续来看prolog能够做一些什么事情吧。
　　理论上来说使用c语言可以编制任何种类的程序，甚至连prolog语言都是使用c语言编写的。不过对于急于开发应用程序的用户，最关心的是如何最经济最有效率的开发程序，prolog为你多提供了一个选择的余地。
　　prolog很适合于开发有关人工智能方面的程序，例如：专家系统、自然语言理解、定理证明以及许多智力游戏。曾经有人预言prolog将成为下一代计算机的主要语言，虽然这个梦想目前还很难实现，不过世界上已经有许多prolog的应用实例了。你要坚信，它绝对不是那种只在实验室发挥作用的语言，之所以大多数人都不了解它，是因为它的应用范围比较特殊而已。
　　prolog有许多不足之处，但是这并不影响它在逻辑推理方面的强大功能，不过最好的方法是使用某种一般语言和prolog结合，一般语言完成计算、界面之类的操作，而prolog则专心实现逻辑运算的操作。例如：你编写一个下棋程序，用prolog来让电脑思考如何下棋，而用Visual Basic来编写界面。我们将在以后介绍这方面的技术。
　　总之，prolog在许多方面将极大的减少你的编程负担，所以赶快来了解一下它吧， 也许你日后遇到什么难题，可以使用prolog迎刃而解，到那个时候，你就知道今天的学习没有白费了。

Prolog的特点¶
　　我个人总结了prolog的以下几个特点，因为叫做特点，所以自然要和其他的语言进行比较。
※prolog程序没有特定的运行顺序，其运行顺序是由电脑决定的，而不是编程序的人。
　　从这个意义上来说，prolog程序不是真正意义上的程序。所谓程序就是按照一定的步骤运行的计算机指令，而prolog程序的运行步骤不由人来决定。它更像一种描述型的语言，用特定的方法描述一个问题，然后由电脑自动找到这个问题的答案。举个极端的例子，你只需要把某个数学题目告诉它，它就会自动的找到答案，而不像使用其他的语言一样，必须人工的编制出某种算法。
※prolog程序中没有if、when、case、for这样的控制流程语句
　　前面已经说了，程序的运行方式由电脑自己决定，当然就用不到这些控制流程的语句了。通常情况下，程序员不需要了解程序的运行过程，只需要注重程序的描述是否全面，不过prolog也提供了一些控制流程的方法，这些方法和其他语言中的方法有很大的区别，希望你在以后的学习当中能够融会贯通。
※prolog程序和数据高度统一
　　在prolog程序中，是很难分清楚哪些是程序，哪些是数据的。事实上，prolog中的所有东西都有相同的形式，也就是说数据就是程序，程序就是数据。举一个其他语言的例子：如果想用c语言编写一个计算某个数学表达式的程序很简单(比如：a=2+5*4)，因为这是一段程序。但是如果想编写一个计算用户输入的表达式的值的程序就很困难了。因为用户输入的是一段数据(字符串)，如果想让c语言处理这个字符串，就需要很多方面的技术。则正是因为在c语言中，程序和数据是分开的。而在prolog就不存在这个问题，你甚至可以很轻松的编写处理其它prolog程序的程序。
※prolog程序实际上是一个智能数据库
　　prolog的原理就是关系数据库，它是建立在关系数据库的基础上的。在以后的学习中你会发现它和SQL数据库查询语言有很多相似之处。使用prolog可以很方便的处理数据。
※强大的递归功能
　　在其它的语言中，你也许已经接触过递归程序了。递归是一种非常简洁的方式，它能够有效的解决许多难题。而在prolog中，递归的功能得到了充分的体现，你甚至都会感到惊奇，递归居然有如此巨大的能力。

下一步该怎么做
　　如果你决定下来要学习prolog了，那么请继续看这里的教程。你要注意哦，这里是目前全球唯一的详细介绍prolog的中文网站。
※在学习之前，希望你能够搞到比较好的prolog解释器，下一节我将就解释器进行一些讨论。
※然后你必须熟练的掌握解释器的使用方法。
※然后就可以开始阅读我的教程了。
※当你学习完整个教程以后，希望你能够进入人工智能实例环节，那里有更多的、更有用的prolog编程方法，和有趣的程序。
※如果你想使用prolog和其它的语言结合起来，编写让人瞠目结舌的又聪明、又漂亮的程序，你就应该仔细研究VB+prolog这一节。
　　好了，还等什么？ 让我们开始吧。

第2章 进入Prolog世界
　　Prolog在英语中的意思就是Programming in LOGic（逻辑编程）。它是建立在逻辑学的理论基础之上的， 最初是运用于自然语言的研究领域。然而现在它被广泛的应用在人工智能的研究中，它可以用来建造专家系统、自然语言理解、智能知识库等。同时它对一些通常的应用程序的编写也很有帮助。使用它能够比其他的语言更快速地开发程序，因为它的编程方法更像是使用逻辑的语言来描述程序。
　　从纯理论的角度来讲，Prolog是一种令人陶醉的编程语言，但是在这本书中还是着重介绍他的实际使用方法。
　　和其他的语言一样，最好的学习方法是实践。这本书将使用Prolog的解释器来向大家介绍几个具体的应用程序的编写过程。
　　首先你应该拥有一个Prolog的解释器，你可以在www*amzi*com找到它。使用它的Editer编写程序，然后存盘，再选择Listener/start，这将打开Prolog的Listener（解释器），最后选择Listener/Consult...，选择你刚才保存的文件，这样你就可以在Listener中调试你的程序了。

2.1 逻辑编程
　　什么叫逻辑编程？也许你还没有一个整体的印象，还是让我们首先来研究一个简单的例子吧。运用经典的逻辑理论，我们可以说“所有的人（person）都属于人类（mortal）”，如果用Prolog的语言来说就是“对于所有的X，只要X是一个人，它就属于人类。”
mortal(X):-person(X).
同样，我们还可以加入一些简单的事实，比如：苏格拉底（socrates）是一个人。
person(socrates).
有了这两条逻辑声明，Prolog就可以判断苏格拉底是不是属于人类。在Prolog的Listener中键入如下的命令：
　　（此句中的“?-”是Listener的提示符，本句表示询问苏格拉底是不是属于人类。）
?-mortal(socrates).
Linstener将给出答案：
yes
我们还可以询问，“谁属于人类？”
?-mortal(X).
我们会得到如下的答案：
X=socrates
　　这个简单的例子显示了Prolog的一些强大的功能。它能让程序代码更简洁、更容易编写。在多数情况下Prolog的程序员不需要关心程序的运行流程，这些都由Prolog自动地完成了。
　　当然，一个完整的程序不能只包括逻辑运算部分，还必须拥有输入输出，乃至用户界面部分。很遗憾，Prolog在这些方面做得不好，或者说很差。不过它还是提供了一些基本的方法的。下面是上述的程序一个完整的例子。
% This is the syntax for comments.
% MORTAL - The first illustrative Prolog program
mortal(X):-person(X).
person(socrates).
person(plato).
person(aristotle).
mortal_report:-
write('Known mortals are:'),
nl,
mortal(X),
write(X),
nl,fail.
把这个程序调入Listener中，运行mortal_report.。
?-mortal_report.
Known mortals are:
socrates
plato
aristotle
no
以上程序中的一些函数以后还会详细的介绍的。最后的那个no表示没有其他的人了。
　　从下一章起，就开始正式介绍Prolog的编程方法了。我将用一个实例来介绍Prolog，这是一个文字的冒险游戏，你所扮演的角色是一个三岁的小女孩，你想睡觉了，可是没有毛毯（nani）你就不能安心的睡觉。所以你必须在那个大房子中找到你的毛毯，这就是你的任务。这个游戏能够显示出一些Prolog的独到之处，不过Prolog的功能远不止编个简单的游戏，所以文中还将介绍一些其他的小程序。

2-2 事实谓词
　　事实（facts）是prolog中最简单的谓词（predicate）。它和关系数据库中的记录十分相似。在下一章中我们会把事实作为数据库来搜索。
谓词
　　Prolog语言的基本组成元素，可以是一段程序、一个数据类型或者是一种关系。它由谓词名和参数组成。两个名称相同而参数的数目不同的谓词是不同的谓词。
　　事实的语法结构如下：
pred(arg1,arg2,...argN).
　　其中pred为谓词的名称。arg1，...为参数，共有N个。‘.’是所有的Prolog子句的结束符。没有参数的谓词形式如下：
pred.
参数可以是以下四种之一：
　　整数（integer）绝对值小于某一个数的正数或负数。
　　原子（atom）由小写字母开头的字符串。
　　变量（variable）由大写字母或下划线（_）开头。
　　结构（structure）在以后的章节介绍。
　　不同的Prolog还增加了一些其他的数据类型，例如浮点数和字符串等。
　　Prolog字符集包括： 大写字母，A-Z；小写字母，a-z；数字，0-9；+-/^,.~:.?#$等。
　　原子通常是字母和数字组成，开头的字符必须是小写字母。例如：
hello
twoWordsTogether
x14
为了方便阅读，可以使用下划线把单词分开。例如：
a_long_atom_name
z_23
下面的是不合法的原子，
no-embedded-hyphens
123nodigitsatbeginning
_nounderscorefirst
Nocapsfirst
使用单引号扩起来的字符集都是合法的原子。例如：
'this-hyphen-is-ok'
'UpperCase'
'embedded blanks'
下面的由符号组成的也是合法的原子：
-->
++
变量和原子相似， 但是开头字符是大写字母或是下划线。例如：
X
Input_List
_4th_argument
Z56
　　有了这些基本的知识，我们就可以开始编写事实了。事实通常用来储存程序所需的数据。例如，某次商业买卖中的顾客数据。customer/3。（/3表示customer有三个参数）
customer('John Jones',boston,good_credit).
customer('Sally Smith',chicago,good_credit).
必须使用单引号把顾客名引起来，因为它们是由大写字母开头的，并且中间有空格。
　　再看一个例子，视窗系统使用事实储存不同的窗口信息。在这个例子中参数有窗口名称和窗口的位置坐标。
window(main,2,2,20,72).
window(errors,15,40,20,78).
　　某个医疗专家系统可能有如下的疾病数据库。
disease(plague,infectious).｛疾病（瘟疫，有传染性）｝
　　Prolog的解释器提供了动态储存事实和规则的方法，并且也提供了访问它们的方法。数据库的更新是通过运consult或reconsult命令。我们也可以直接在解释器中输入谓词，但是这些谓词不会被储存到硬盘上。

2-3 简单查询
　　现在我们的游戏中已经有了一些事实，使用Prolog的解释器调入此程序后，我们就可以对这些事实进行查询了。本章和下一章中的Prolog程序只包括事实，我们要学会如何对这些事实进行查询。
　　Prolog的查询工作是靠模式匹配完成的。查询的模板叫做目标(goal)。如果有某个事实与目标匹配，那么查询就成功了，Prolog的解释器会回显’yes’。如果没有匹配的事实，查询就失败了，解释器回显'no'。
　　我们把Prolog的模式匹配工作叫做联合(unification)。当数据库中只包括事实时，以下三个条件是使联合成功的必要条件。
● 目标谓词名与数据库中的某个谓词名相同。
● 这两个谓词的参数数目相同。
● 所有的参数也相同。
在介绍查询之前，让我们回顾一下上一章所编写的Prolog程序。
room(kitchen).
room(office).
room(hall).
room('dining room').
room(cellar).
door(office,hall).
door(kitchen,office).
door(hall,'dining room').
door(kitchen,cellar).
door('dining room',kitchen).
location(desk,office).
location(apple,kitchen).
location(flashlight,desk).
location('washing machine',cellar).
location(nani,'washing machine').
location(broccoli,kitchen).
location(crackers,kitchen).
location(computer,office).
edible(apple).
edible(crackers).
tastes_yucky(broccoli).
here(kitchen).
以上是我们的“寻找Nani”中的所有事实。把这段程序调入Prolog解释器中后就可以开始进行查询了。
我们的第一个问题是：office在本游戏中是不是一个房间。
?-room(office).｛?-是解释器的提示符｝
yes
Prolog回答yes，因为它在数据库中找到了room(office).这个事实。我们继续问：有没有attic这个房间。
?-room(attic).
no
Prolog回答no，因为它在数据库中找不到room(attic).这个事实。同样我们还可以进行如下的询问。
?-location(apple,kitchen).
yes
?-location(kitchen,apple).
no
你看Prolog懂我们的意思呢，它知道苹果在厨房里，并且知道厨房不在苹果里。但是下面的询问就出问题了。
?-door(office,hall).
yes
?-door(hall,office).
no
由于我们定义的门是单方向的，结果遇到了麻烦。
　　在查询目标中我们还可以使用Prolog的变量。这种变量和其他语言中的不同。叫它逻辑变量更合适一点。变量可以代替目标中的一些参数。
　　变量给联合操作带来了新的意义。以前联合操作只有在谓词名和参数都相同时才能成功。但是引入了变量之后，变量可以和任何的条目匹配。
　　当联合成功之后，变量的值将和它所匹配的条目的值相同。这叫做变量的绑定(binding)。当带变量的目标成功的和数据库中的事实匹配之后，Prolog将返回变量绑定的值。
　　由于变量可能和多个条目匹配，Prolog允许你察看其他的绑定值。在每次Prolog的回答后输入“;”，可以让Prolog继续查询。下面的例子可以找到所有的房间。“;”是用户输入的。
?-room(X).
X=kitchen;
X=office;
X=hall;
X='dining room';
X=cellar;
no
最后的no表示找不到更多的答案了。
下面我们想看看kitchen中都有些什么。（变量以大写字母开始）
?-location(Thing,kitchen).
Thing=apple;
Thing=broccoli;
Thing=crackers;
no
我们还可以使用两个变量来查询所有的物体及其位置。
?-location(Thing,Place).
Thing=desk
Place=office;
Thing=apple
Place=kitchen;
Thing=flashlight
Place=desk;
...
no

查询的工作原理
　　当Prolog试图与某一个目标匹配时，例如：location/2，它就在数据库中搜寻所有用location/2定义的子句，当找到一条与目标匹配时，它就为这条子句作上记号。当用户需要更多的答案时，它就从那条作了记号的子句开始向下查询。
　　我们来看一个例子，用户询问：location(X,kitchen).。Prolog找到数据库中的第一条location/2子句，并与目标比较。
目标 子句#1
location(X,kitchen) location(desk,office)
匹配失败，因为第二个参数不同，一个是kitchen，一个是office。于是Prolog继续比较第二个子句。
目标 子句#2
location(X,kitchen) location(apple,kitchen)
这回匹配成功，而变量X的值就被绑定成了apple。
?-location(X,kitchen).
X=apple
　　如果用户输入分号(;)，Prolog就开始寻找其他的答案。首先它必须释放（unbinds）变量X。然后从上一次成功的位置的下一条子句开始继续搜索。这个过程叫做回溯（backtracking）。在本例中就是第三条子句。
目标 子句#3
location(X,kitchen) location(flashlight,desk)
匹配失败，直到第六条子句时匹配又成功了 。
目标 子句#6
location(X,kitchen) location(broccoli,kitchen)
结果变量X又被绑定为broccoli，解释器显示：
X=broccoli;
再度输入分号，X又被解放，开始新的搜索。又找到了：
X=crackers;
这回再没有新的子句能够匹配了，于是Prolog回答no，表示最后一次搜索失败了。
no
　　要想了解Prolog的运行顺序，最好的方法就是单步调试程序，不过在此之前，还是让我们加深一下对目标的认识吧。
　　Prolog的目标有四个端口用来控制运行的流程：调用（call）、退出（exit）、重试（redo）以及失败（fail）。一开始使用Call端口进入目标，如果匹配成功就到了exit端口，如果失败就到了fail端口，如果用户输入分号，则又从redo端口进入目标。下图表示了目标和它的四个端口。

每个端口的功能如下：
● call 开始使用目标搜寻子句。
● exit 目标匹配成功，在成功的子句上作记号，并绑定变量。
● redo 试图重新满足目标，首先释放变量，并从上次的记号开始搜索。
● fail 表示再找不到更多的满足目标的子句了。
下面列出了调试location(X,kitchen).时的情况。括号中的数字表示当前正在考虑的子句。
?-location(X,kitchen).
CALL:location(X,kitchen)
EXIT:(2)location(apple,kitchen)
X=apple;
REDO:location(X,kitchen)
EXIT:(6)location(broccoli,kitchen)
X=broccoli;
REDO:location(X,kitchen)
EXIT:(7)location(crackers,kitchen)
X=crackers;
FAIL:location(X,kitchen)
no
在Prolog的解释器中输入，
?-debug.
就可以开始调试你的程序了。
　　下一节中将介绍更为复杂的查询。

楼主你好，我回帖不知道为什么被删了。我私信你显示你拒绝陌生人私信。能麻烦你私信我一下吗？谢谢了。

你好，我们互相关注了，但是还是显示你拒收了我的私信。

我也很绝望，不知道为什么。。。

好像我的发帖也被隐藏了。不知道触发了什么关键字。请问能加你QQ吗？

您好，诚心有prolog问题求教，但是我发帖总是发不上来。能方便加一下qq吗？有偿。谢谢了！